Blog

有關這些功能的更多信息：

• 閱讀文檔中的ESP-NOW文檔
• 樂鑫ESP8266 API參考

ESP8266 NodeMCU發送方草稿圖（ESP-NOW）

以下是ESP8266 NodeMCU Sender開發板的程式碼。將程式碼複製到您的Arduino IDE，上傳前，您需要先進行一些修改。

/*
  Terry Lee
  完整說明請參閱 http://honeststore.com.tw/blog/esp8266-esp-now/
*/

#include <ESP8266WiFi.h> 
#include <espnow.h> 

// 替換成接收方的MAC Address
uint8_t broadcastAddress[] = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF};

// 結構範例發送數據必須匹配接收方結構
typedef struct struct_message {
  char a[32];
  int b;
  float c;
  String d;
  bool e;
} struct_message;

// 新建一個訊息傳送結構，變數名稱叫myData
struct_message myData;

unsigned long lastTime = 0;  
unsigned long timerDelay = 2000;  // 發送讀數計時器

// 發送數據時的回饋函數
void OnDataSent(uint8_t *mac_addr, uint8_t sendStatus) {
  Serial.print("Last Packet Send Status: ");
  if (sendStatus == 0){
    Serial.println("Delivery success");
  }
  else{
    Serial.println("Delivery fail");
  }
}
 
void setup() {
  // Init Serial Monitor
  Serial.begin(115200);
 
  // 將設備設置為Wi-Fi工作站
  WiFi.mode(WIFI_STA);

  // Init ESP-NOW
  if (esp_now_init() != 0) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }

  // 一旦Espnow成功初始化，我們將註冊發送回饋函數至獲取數據包的狀態  
  esp_now_set_self_role(ESP_NOW_ROLE_CONTROLLER);
  esp_now_register_send_cb(OnDataSent);
  
  // 註冊同行
  esp_now_add_peer(broadcastAddress, ESP_NOW_ROLE_SLAVE, 1, NULL, 0);
}
 
void loop() {
  if ((millis() - lastTime) > timerDelay) {
    // 設定預發送的值
    strcpy(myData.a, "THIS IS A CHAR");
    myData.b = random(1,20);
    myData.c = 1.2;
    myData.d = "Hello";
    myData.e = false;

    // 從ESP-NOW傳送訊息
    esp_now_send(broadcastAddress, (uint8_t *) &myData, sizeof(myData));

    lastTime = millis();
  }
}

程式碼如何工作

首先，包括 ESP8266WiFi.h 和 espnow.h 庫。

#include <ESP8266WiFi.h> 
#include <espnow.h> 

在下一行中，應插入ESP8266接收器MAC地址。

uint8_t broadcastAddress[] = {0x5C, 0xCF, 0x7F, 0x99, 0x9A, 0xEA};

在我們的例子中，接收者的MAC地址是： 5C：CF：7F：99：9A：EA，但您需要用自己的MAC地址替換該變量。 然後，建立一個包含我們要發送的數據類型的結構。我們稱這種結構struct_message它包含5種不同的變數類型。您可以更改它以發送所需的任何變量類型。

typedef struct struct_message {
  char a[32];
  int b;
  float c;
  String d;
  bool e;
} struct_message;

建一個新的類型變數 struct_message 它被稱作 myData 將存儲變數值。

struct_message myData;

接下來，定義 OnDataSent（）功能。這是一個回饋函數，將在發送消息時執行。在這種情況下，無論是否成功發送此消息，都只會印出該消息。

void OnDataSent(uint8_t *mac_addr, uint8_t sendStatus) {
  Serial.print("Last Packet Send Status: ");
  if (sendStatus == 0){
    Serial.println("Delivery success");
  }
  else{
    Serial.println("Delivery fail");
  }
}

在setup（）裡，初始化序列監視器以進行調試：

Serial.begin(115200);

將設備設置為Wi-Fi工作站點：

WiFi.mode(WIFI_STA);

初始化ESP：

if (esp_now_init() != 0) {
  Serial.println("Error initializing ESP-NOW");
  return;
}

設置ESP8266角色：

esp_now_set_self_role(ESP_NOW_ROLE_CONTROLLER);

它接受以下角色： ESP_NOW_ROLE_CONTROLLER， ESP_NOW_ROLE_SLAVE， ESP_NOW_ROLE_COMBO， ESP_NOW_ROLE_MAX。

成功初始化ESP-NOW之後，註冊將在發送消息時調用的回饋函數。在這種情況下，我們註冊OnDataSent（） 先前建置的功能。

esp_now_register_send_cb(OnDataSent);

然後，與另一個ESP-NOW設備配對以發送數據：

esp_now_add_peer(broadcastAddress, ESP_NOW_ROLE_SLAVE, 1, NULL, 0);

esp_now_add_peer 按此順序接受以下參數：mac address，role，Wi-Fi channel，key和key長度。 在loop（）裡，我們將每2秒通過ESP-NOW發送一條消息（您可以更改延時時間在 timerDelay 變數）。 首先，我們將變數值設置如下：

strcpy(myData.a, "THIS IS A CHAR");
myData.b = random(1,20);
myData.c = 1.2;
myData.d = "Hello";
myData.e = false;

請記住 myData是一個結構。在這裡，我們分配要在結構內部發送的值。例如，第一行分配一個char，第二行分配一個隨機的Int，一個Float，一個String和一個Boolean變數。 我們建立這種結構來向您展示如何發送最常見的變數類型。您可以更改結構以發送任何其他類型的數據。 最後，發送消息如下：

esp_now_send(broadcastAddress, (uint8_t *) &myData, sizeof(myData));

loop（） 函數裡，每2000毫秒（2秒）執行一次。

if ((millis() - lastTime) > timerDelay) {
  // Set values to send
  strcpy(myData.a, "THIS IS A CHAR");
  myData.b = random(1,20);
  myData.c = 1.2;
  myData.d = "Hello";
  myData.e = false;

  // Send message via ESP-NOW
  esp_now_send(broadcastAddress, (uint8_t *) &myData, sizeof(myData));

  lastTime = millis();
}

ESP8266 NodeMCU接收器草稿圖（ESP-NOW）

將以下程式碼上傳至ESP8266 NodeMCU接收板。

/*
  Terry Lee
  完整說明請參閱 http://honeststore.com.tw/blog/esp8266-esp-now/
*/

#include <ESP8266WiFi.h> 
#include <espnow.h> 

// 結構範例接收數據必須匹配發送方結構
typedef struct struct_message {
    char a[32];
    int b;
    float c;
    String d;
    bool e;
} struct_message;

// 新建一個訊息接收結構，變數名稱叫myData
struct_message myData;

// 收到數據時將執行的回饋函數
void OnDataRecv(uint8_t * mac, uint8_t *incomingData, uint8_t len) {
  memcpy(&myData, incomingData, sizeof(myData));
  Serial.print("Bytes received: ");
  Serial.println(len);
  Serial.print("Char: ");
  Serial.println(myData.a);
  Serial.print("Int: ");
  Serial.println(myData.b);
  Serial.print("Float: ");
  Serial.println(myData.c);
  Serial.print("String: ");
  Serial.println(myData.d);
  Serial.print("Bool: ");
  Serial.println(myData.e);
  Serial.println();
}
 
void setup() {
  // Initialize Serial Monitor
  Serial.begin(115200);
  
  // 將設備設置為Wi-Fi工作站
  WiFi.mode(WIFI_STA);

  // Init ESP-NOW
  if (esp_now_init() != 0) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }
  
  // 一旦Espnow成功初始化，我們將註冊發送回饋函數至獲取數據包的狀態
  esp_now_set_self_role(ESP_NOW_ROLE_SLAVE);
  esp_now_register_recv_cb(OnDataRecv);
}

void loop() {
  
}

程式碼如何工作

與發送方類似，首先包括以下庫：

#include <ESP8266WiFi.h> 
#include <espnow.h> 

建立一個結構以接收數據。此結構應與發件人草稿圖中定義的結構相同。

typedef struct struct_message {
  char a[32];
  int b;
  float c;
  String d;
  bool e;
} struct_message;

建立一個 struct_message 變數稱為 myData。

struct_message myData;

建立一個回饋函數，當ESP8266通過ESP-NOW接收數據時將調用該函數。該函數稱為onDataRecv（） 並應接受以下幾個參數：

void OnDataRecv(const uint8_t * mac, const uint8_t *incomingData, int len) {

我們複製內容將 incomingData 數據變數放入 myData 變數中。

memcpy(&myData, incomingData, sizeof(myData));

現在 myData結構內部包含幾個變數，以及發送方ESP8266發送的值。例如，訪問變數a，我們只需要呼叫 myData.a。 在此範例中，我們僅印出接收到的數據，但是在實際應用中，您可以在顯示器上印出數據。

Serial.print("Bytes received: ");
  Serial.println(len);
  Serial.print("Char: ");
  Serial.println(myData.a);
  Serial.print("Int: ");
  Serial.println(myData.b);
  Serial.print("Float: ");
  Serial.println(myData.c);
  Serial.print("String: ");
  Serial.println(myData.d);
  Serial.print("Bool: ");
  Serial.println(myData.e);
  Serial.println();
}

在 setup（）裡，初始化序列通信以進行調試。

Serial.begin(115200);

將設備設置為Wi-Fi工作站。

WiFi.mode(WIFI_STA);

初始化ESP：

if (esp_now_init() != ESP_OK) {
  Serial.println("Error initializing ESP-NOW");
  return;
}

設置ESP8266角色：

esp_now_set_self_role(ESP_NOW_ROLE_SLAVE);

註冊接收數據時將調用的回饋函數。在這種情況下，我們註冊OnDataRecv（） 先前建置的功能。

esp_now_register_recv_cb(OnDataRecv);