要建立 ESP32 BLE 服務器，請打開您的 Arduino IDE 並轉到 檔案>範例> ESP32 BLE Arduino並選擇BLE_server範例。載入以下程式碼：

/*
    Based on Neil Kolban example for IDF: https://github.com/nkolban/esp32-snippets/blob/master/cpp_utils/tests/BLE%20Tests/SampleServer.cpp
    Ported to Arduino ESP32 by Evandro Copercini
    updates by chegewara
*/

#include <BLEDevice.h>
#include <BLEUtils.h>
#include <BLEServer.h>

// See the following for generating UUIDs:
// https://www.uuidgenerator.net/

#define SERVICE_UUID        "4fafc201-1fb5-459e-8fcc-c5c9c331914b"
#define CHARACTERISTIC_UUID "beb5483e-36e1-4688-b7f5-ea07361b26a8"

void setup() {
  Serial.begin(115200);
  Serial.println("Starting BLE work!");

  BLEDevice::init("Long name works now");
  BLEServer *pServer = BLEDevice::createServer();
  BLEService *pService = pServer->createService(SERVICE_UUID);
  BLECharacteristic *pCharacteristic = pService->createCharacteristic(
                                         CHARACTERISTIC_UUID,
                                         BLECharacteristic::PROPERTY_READ |
                                         BLECharacteristic::PROPERTY_WRITE
                                       );

  pCharacteristic->setValue("Hello World says Neil");
  pService->start();
  // BLEAdvertising *pAdvertising = pServer->getAdvertising();  // this still is working for backward compatibility
  BLEAdvertising *pAdvertising = BLEDevice::getAdvertising();
  pAdvertising->addServiceUUID(SERVICE_UUID);
  pAdvertising->setScanResponse(true);
  pAdvertising->setMinPreferred(0x06);  // functions that help with iPhone connections issue
  pAdvertising->setMinPreferred(0x12);
  BLEDevice::startAdvertising();
  Serial.println("Characteristic defined! Now you can read it in your phone!");
}

void loop() {
  // put your main code here, to run repeatedly:
  delay(2000);
}

要建立 BLE 服務器，程式碼應遵循以下步驟：

1. 建立一個 BLE 服務器。在這種情況下，ESP32充當BLE服務器。
2. 建立 BLE 服務。
3. 在服務上建立 BLE 特徵。
4. 在特徵上建立一個 BLE 描述。
5. 啟動服務。
6. 開始廣播，以便其他設備可以找到它。

程代碼如何工作

讓我們快速了解一下 BLE 服務器範例程式碼是如何工作的。 它首先導入 BLE 功能所需的庫。

#include <BLEDevice.h>
#include <BLEUtils.h>
#include <BLEServer.h>

然後，您需要為 Service 和 Characteristic 定義一個 UUID。

#define SERVICE_UUID "4fafc201-1fb5-459e-8fcc-c5c9c331914b"
#define CHARACTERISTIC_UUID "beb5483e-36e1-4688-b7f5-ea07361b26a8"

您可以保留預設 UUID，也可以訪問 uuidgenerator.net 為您的服務和特徵建立隨機 UUID。 在 setup（）裡，它以 115200 的波特率啟動串行通信。

Serial.begin(115200);

然後，您建立一個名為“ MyESP32 ”的 BLE 設備。您可以將此名稱更改為您想要的任何名稱。

// Create the BLE Device
BLEDevice::init("MyESP32");

在以下行中，您將 BLE 設備設置為服務器。

BLEServer *pServer = BLEDevice::createServer();

接著，再使用之前定義的 UUID 為 BLE 服務器建立服務。

 BLEService *pService = pServer->createService(SERVICE_UUID);

然後，您設置該服務的特徵。如所見，您還使用了之前定義的 UUID，您需要將特徵的屬性作為參數傳遞。在這種情況下，它是：讀和寫。

BLECharacteristic *pCharacteristic = pService->createCharacteristic(
                                     CHARACTERISTIC_UUID,
                                     BLECharacteristic::PROPERTY_READ |
                                     BLECharacteristic::PROPERTY_WRITE
                                     );

建立特徵後，您可以使用 setValue（） 方法。

pCharacteristic->setValue("Hello World says Neil");

最後，您可以啟動服務和廣播，以便其他 BLE 設備可以掃描並找到此 BLE 設備。

BLEAdvertising *pAdvertising = pServer->getAdvertising();
pAdvertising->start();

這只是一個關於如何建立 BLE 服務器的簡單範例。在這段程式碼中沒有做任何事情loop（），但您可以新增新客戶端連接時發生的情況（請看 BLE_notify 範例以獲取一些指導）。