Blog

所需零件

以下是完成本節所需的零件列表：

• ESP8266
• PIR被動感測器（HC-SR501）
• 5mm LED
• 330歐姆電阻
• 麵包板
• 跳線

原理圖，示意圖

將PIR被動感測器和一個LED組裝到ESP8266。我們將LED連接到GPIO 12 （D6）和PIR被動感測器引腳連接到 GPIO 14 （D5）。

重要：此項目中使用的HC-SR501 PIR被動感測器的工作電壓為5V。但是，如果您使用的是Mini AM312之類的其他PIR被動感測器，則其工作電壓為3.3V。您可以將其修改為在5V下工作，也可以使用Vin引腳簡單地為其供電。

程式碼

如示意圖所示對電路進行接線後，將提供的程式碼複製到Arduino IDE。

您可以按原樣上傳代碼，也可以修改檢測到運動後LED點亮的秒數。只需更改timeSeconds 變數與您想要的秒數。

/*********
  Terry Lee
  完整說明請參閱 http://honeststore.com.tw  
*********/

#define timeSeconds 3

// 設定LED和PIR Motion Sensor的引腳變數
const int led = D6;
const int motionSensor = D5;

// 計時器：輔助變量
unsigned long now = millis();
unsigned long lastTrigger = 0;
boolean startTimer = false;

// 檢查是否檢測到動作，設置LED高位並啟動計時器
ICACHE_RAM_ATTR void detectsMovement() {
  Serial.println("偵測物體在移動!!!");
  digitalWrite(led, HIGH);
  startTimer = true;
  lastTrigger = millis();
}

void setup() {
  // Serial port for debugging purposes
  Serial.begin(115200);
  
  // PIR Motion Sensor mode INPUT_PULLUP
  pinMode(motionSensor, INPUT_PULLUP);
  // 將Motionsensor引腳設置為中斷，分配中斷功能並設置上升模式
  attachInterrupt(digitalPinToInterrupt(motionSensor), detectsMovement, RISING);

  // Set LED to LOW
  pinMode(led, OUTPUT);
  digitalWrite(led, LOW);
}

void loop() {
  // 目前時間
  now = millis();
  // 在timeSeconds變數中定義的秒數後關閉
  if(startTimer && (now - lastTrigger > (timeSeconds*1000))) {
    Serial.println("物體移動停止...");
    digitalWrite(led, LOW);
    startTimer = false;
  }
}

程式碼如何工作

讓我們看一下程式碼。

首先將兩個GPIO引腳設定為 LED 和 PIR被動感測器 變數。

const int led = D6;
const int motionSensor = D5;

然後，建立變數，該變數將允許您設定計時器以在檢測到物體移動後關閉LED。

unsigned long now = millis();
unsigned long lastTrigger = 0;
boolean startTimer = false;

now變數保存當前時間。lastTrigger變數保存PIR被動感測器檢測到物體運動的時間。startTimer 是一個布林變數，在檢測到運動時啟動計時器。

setup（）

在 setup（）裡面，首先以115200鮑率初始化序列端口。

Serial.begin(115200);

將PIR被動感測器設置為 INPUT_PULLUP。

pinMode(motionSensor, INPUT_PULLUP);

要將PIR被動感測器引腳設置為中斷功能，請使用 attachInterrupt（） 功能如前所述。

attachInterrupt(digitalPinToInterrupt(motionSensor), detectsMovement, RISING);

GPIO 14引腳將檢測物體移動的數數，它會調用 detectorMovement（）函數在 RISING 模式。

LED是一個 OUTPUT 其狀態預設為LOW

pinMode(led, OUTPUT);
digitalWrite(led, LOW);

loop（）

loop（）功能是不斷地反復運行。在每個循環中，now 變數會一直更新成為當前時間。

now = millis();

在 loop（）函數中基本上是沒有動作。只是，當PIR檢測到物體移動時，detectorMovement（）函數會被調用。因為我們在 setup（）函數中已經設定中斷的函數。

detectorMovement（）函數功能為在序列監視器中印出”偵測物體在移動!!!”消息，開啟LED，設置 startTimer 布林變數值為true並且更新 lastTrigger 變數值為當前時間。

// 檢查是否檢測到動作，設置LED高位並啟動計時器
ICACHE_RAM_ATTR void detectsMovement() {
  Serial.println("偵測物體在移動!!!");
  digitalWrite(led, HIGH);
  startTimer = true;
  lastTrigger = millis();
}

完成此步驟後，程式碼將返回到 loop（）函數。這時，startTimer變數值是true。因此，now減掉lastTrigger時間差若大於我們設定的時間（當檢測到物體移動後動作），則if語句的斷判為true。

 // 在timeSeconds變數中定義的秒數後關閉
  if(startTimer && (now - lastTrigger > (timeSeconds*1000))) {
    Serial.println("物體移動停止...");
    digitalWrite(led, LOW);
    startTimer = false;
  }

“ 物體移動停止…”消息將在序列監視器中印出，LED熄滅，並且 startTimer 變數值設置為false。