Blog

ESP8266 Client是連接到ESP8266 Server的Wi-Fi站點。客戶端通過在Server上發出HTTP GET請求，從Server請求溫度，濕度和壓力。/temperature， /humidity和 /pressure URL路由。然後，它將讀數顯示在OLED顯示器上。

原理圖，示意圖

如下圖所示，將OLED顯示器連接到ESP8266板上。

適用於＃2 ESP8266 Client的Arduino Sketch草稿碼

將以下程式碼上傳到ESP8266（客戶端）開發板：

/*
  Terry Lee
  完整說明請參閱 http://honeststore.com.tw/
*/

#include <ESP8266WiFi.h> 
#include <ESP8266HTTPClient.h> 
#include <WiFiClient.h> 

#include <ESP8266WiFiMulti.h> 
ESP8266WiFiMulti WiFiMulti;

const char* ssid = "ESP8266-AP";
const char* password = "123456789";

//您的IP地址或帶URL路徑的域名
const char* serverNameTemp = "http://192.168.4.1/temperature";
const char* serverNameHumi = "http://192.168.4.1/humidity";
const char* serverNamePres = "http://192.168.4.1/pressure";

#include <Wire.h> 
#include <Adafruit_GFX.h> 
#include <Adafruit_SSD1306.h> 

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

String temperature;
String humidity;
String pressure;

unsigned long previousMillis = 0;
const long interval = 5000; 

void setup() {
  Serial.begin(115200);
  Serial.println();
  
  // Address 0x3C for 128x64, you might need to change this value (use an I2C scanner)
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }
  display.clearDisplay();
  display.setTextColor(WHITE);
 
  WiFi.mode(WIFI_STA);
  WiFiMulti.addAP(ssid, password);
  while((WiFiMulti.run() == WL_CONNECTED)) { 
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("Connected to WiFi");
}

void loop() {
  unsigned long currentMillis = millis();
  
  if(currentMillis - previousMillis >= interval) {
     // Check WiFi connection status
    if ((WiFiMulti.run() == WL_CONNECTED)) {
      temperature = httpGETRequest(serverNameTemp);
      humidity = httpGETRequest(serverNameHumi);
      pressure = httpGETRequest(serverNamePres);
      Serial.println("Temperature: " + temperature + " *C - Humidity: " + humidity + " % - Pressure: " + pressure + " hPa");
      
      display.clearDisplay();
      
      // display temperature
      display.setTextSize(2);
      display.setCursor(0,0);
      display.print("T: ");
      display.print(temperature);
      display.print(" ");
      display.setTextSize(1);
      display.cp437(true);
      display.write(248);
      display.setTextSize(2);
      display.print("C");
      
      // display humidity
      display.setTextSize(2);
      display.setCursor(0, 25);
      display.print("H: ");
      display.print(humidity);
      display.print(" %"); 
      
      // display pressure
      display.setTextSize(2);
      display.setCursor(0, 50);
      display.print("P:");
      display.print(pressure);
      display.setTextSize(1);
      display.setCursor(110, 56);
      display.print("hPa");
           
      display.display();
      
      // save the last HTTP GET Request
      previousMillis = currentMillis;
    }
    else {
      Serial.println("WiFi Disconnected");
    }
  }
}

String httpGETRequest(const char* serverName) {
  WiFiClient client;
  HTTPClient http;
    
  // Your IP address with path or Domain name with URL path 
  http.begin(client, serverName);
  
  // Send HTTP POST request
  int httpResponseCode = http.GET();
  
  String payload = "--"; 
  
  if (httpResponseCode>0) {
    Serial.print("HTTP Response code: ");
    Serial.println(httpResponseCode);
    payload = http.getString();
  }
  else {
    Serial.print("Error code: ");
    Serial.println(httpResponseCode);
  }
  // Free resources
  http.end();

  return payload;
}

程式碼如何工作

包括用於Wi-Fi連接和發出HTTP請求所需的庫：

#include <ESP8266WiFi.h> 
#include <ESP8266HTTPClient.h> 
#include <WiFiClient.h> 

#include <ESP8266WiFiMulti.h> 

您需要建立一個 WiFiMulti instance。

ESP8266WiFiMulti WiFiMulti;

插入ESP8266 Server網路證書。如果您已更改ESP8266 Server中的預設網路憑據，則應在此處進行更改以匹配。

const char* ssid = "ESP8266-AP";
const char* password = "123456789";

然後，保存客戶端將在其中發出HTTP請求的URL。ESP8266 Server具有192.168.4.1 IP地址，我們將加上/temperature， /humidity 和 /pressure 網址。

const char* serverNameTemp = "http://192.168.4.1/temperature";
const char* serverNameHumi = "http://192.168.4.1/humidity";
const char* serverNamePres = "http://192.168.4.1/pressure";

載入OLED顯示器接口的庫：

#include <Wire.h> 
#include <Adafruit_GFX.h> 
#include <Adafruit_SSD1306.h> 

設置OLED顯示尺寸：

#define SCREEN_WIDTH 128  // OLED display width, in pixels
#define SCREEN_HEIGHT 64  // OLED display height, in pixels

建立一個 display 具有您之前定義的大小並具有I2C通信協議的物件。

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

初始化將保存Server檢索的溫度，濕度和壓力讀數的字符串變數。

String temperature;
String humidity;
String pressure;

設置每個請求之間的時間間隔。預設情況下，它設置為5秒，但是您可以將其更改為任何其他時間間隔。

const long interval = 5000; 

在setup（）裡，初始化OLED顯示：

// Address 0x3C for 128x64, you might need to change this value (use an I2C scanner)
if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
  Serial.println(F("SSD1306 allocation failed"));
  for(;;); // Don't proceed, loop forever
}
display.clearDisplay();
display.setTextColor(WHITE);

注意：如果您的OLED顯示器無法正常工作，請使用I2C掃描儀草圖檢查其I2C地址，並相應地更改程式碼。

將ESP8266客戶端連接到ESP8266 Server網路。

WiFi.mode(WIFI_STA);
WiFiMulti.addAP(ssid, password);
while((WiFiMulti.run() == WL_CONNECTED)) { 
  delay(500);
  Serial.print(".");
}
Serial.println("");
Serial.println("Connected to WiFi");

在 loop（）是我們發出HTTP GET請求的地方。我們建立了一個名為httpGETRequest（） 接受我們要發出String(字串)請求的URL路徑作為參數。

您可以在項目中使用下列函數來簡化程式碼：

String httpGETRequest(const char* serverName) {
  WiFiClient client;
  HTTPClient http;
    
  // Your IP address with path or Domain name with URL path 
  http.begin(client, serverName);
  
  // Send HTTP POST request
  int httpResponseCode = http.GET();
  
  String payload = "--"; 
  
  if (httpResponseCode>0) {
    Serial.print("HTTP Response code: ");
    Serial.println(httpResponseCode);
    payload = http.getString();
  }
  else {
    Serial.print("Error code: ");
    Serial.println(httpResponseCode);
  }
  // Free resources
  http.end();

  return payload;
}

我們使用該功能從Server獲取溫度，濕度和壓力讀數。

temperature = httpGETRequest(serverNameTemp);
humidity = httpGETRequest(serverNameHumi);
pressure = httpGETRequest(serverNamePres);

在序列監視器中印出這些讀數以進行測試。

Serial.println("Temperature: " + temperature + " *C - Humidity: " + humidity + " % - Pressure: " + pressure + " hPa");

然後，在OLED顯示器中顯示溫度：

display.setTextSize(2);
display.setTextColor(WHITE);
display.setCursor(0,0);
display.print("T: ");
display.print(temperature);
display.print(" ");
display.setTextSize(1);
display.cp437(true);
display.write(248);
display.setTextSize(2);
display.print("C");

濕度：

display.setTextSize(2);
display.setCursor(0, 25);
display.print("H: ");
display.print(humidity);
display.print(" %"); 

最後，壓力讀數：

display.setTextSize(2);
display.setCursor(0, 50);
display.print("P:");
display.print(pressure);
display.setTextSize(1);
display.setCursor(110, 56);
display.print("hPa");

display.display();

我們使用計時器而不是延遲來每x秒發送一個請求。這就是為什麼我們有previousMillis、 currentMillis 變數並使用 millis（）功能。我們有一篇文章介紹了計時器和延遲之間的差異，您可能會發現這很有用（或閱讀ESP8266 Timers）。

將草稿碼上傳到＃2 ESP8266（客戶端）以測試一切是否正常。

測試ESP8266客戶端

將兩塊板都關閉並加電後，您會看到ESP＃2每隔5秒從ESP＃1接收一次新的溫度，濕度和壓力讀數。

這是您應該在ESP8266 Client Serial Monitor上看到的內容。

感測器讀數也顯示在OLED中。

就是這樣！兩個ESP8266開發板彼此通信就是這樣溝通。